| Предыдущая тема :: Следующая тема |
| Автор |
Сообщение |
vadim_k80
Зарегистрирован: 17.10.2005
Сообщения: 5
Откуда: г. Барнаул
|
 Добавлено: Пн Окт 17 2005 05:17 Заголовок сообщения: Как программно отключить сетевую карту? |
 |
|
| Подскажите... как можно программно (через командную строку) отключить сетевую карту в ОС Server 2003? |
|
| Вернуться к началу |
|
 |
4u3u
Зарегистрирован: 24.01.2003
Сообщения: 997
Откуда: Moscow
|
| Добавлено: Пн Окт 17 2005 12:18 Заголовок сообщения: |
|
|
devcon.exe
http://support.microsoft.com//kb/311272
| Код: | ::***********************************************************************
:: Name: denic.cmd
::
:: Purpose: Disables/Enables PCI network cards using devcon.exe utility
::
:: Requires: Windows 2000 or newer
:: Device Console (devcon.exe). Download from
:: http://support.microsoft.com/kb/311272
::
:: Version: 1.2
::
:: Authors: Alexander Suhovey
::***********************************************************************
@echo off
setlocal ENABLEDELAYEDEXPANSION
::========= OS Check ============
if not "%OS%" == "Windows_NT" goto BADOS
if "%APPDATA%" == "" goto BADOS
::==== Parsing command line =====
if not "%1"=="-d" (
if not "%1"=="-e" (
goto SYNTAX
) Else (set action=enable)
) Else (set action=disable)
if "%~2"=="" (
set found=1
set out=any PCI network card.
set out1=Try different search criteria ^(see 'devcon find' string in the script^)
) Else (
set out=network card^: "%~2"
)
::======== Main section =========
for /f "tokens=1,2 delims=:" %%i in ('devcon find ^=Net PCI\*') do (
if not "%%i"=="No matching devices found." (
set id=%%i
set disp_name=%%j
set disp_name="!disp_name:~1!"
if "%~2"==!disp_name! set found=1
if !found!==1 (
echo Device found^: !disp_name!
echo Device ID^: !id!
echo.
set id=@!id:^&=*!
for /f "skip=2 tokens=3 delims= " %%o in ('devcon status !id! ^| find /v "matching device" ') do (
set state=%%o
set state=!state:~0,-2!
If "%action%"=="!state:runnin=enable!" (
echo Device is already %action%d.
goto :eof
)
)
rem ==================================
rem SAFETY LOCK: Remove 'echo' at next
rem line to perform action on device
rem ==================================
echo devcon %action% !id!
goto :eof
)
)
)
goto NONIC
::===== Wrong OS handling =======
:BADOS
echo.
echo ERROR^: This script needs Windows 2000 or better.
goto :eof
::======== NIC not found ========
:NONIC
echo ERROR^: Cannot find %out%
If not "%out1%"=="" echo %out1%
goto :eof
::=========Script syntax ========
:SYNTAX
echo.
echo %~nx0
echo Disables/enables PCI network card.
echo.
echo SYNTAX: %~nx0 ^<-e^|-d^> [display_name]
echo.
echo -e : Enable network card
echo -d : Disable network card
echo display_name : Network card display name
echo (e.g. from Device Manager)
echo Examples:
echo.
echo %~nx0 -d
echo Disables first network card found.
echo.
echo %~nx0 -e "Intel(R) PRO/1000 MT Mobile Connection"
echo Enables network card with corresponding display name.
goto :eof
::======= End of script ========= |
|
|
| Вернуться к началу |
|
|
vadim_k80
Зарегистрирован: 17.10.2005
Сообщения: 5
Откуда: г. Барнаул
|
|
| Вернуться к началу |
|
|
|
FAQ 
Поиск 
Пользователи 
Группы
Регистрация
Профиль 
Войти и проверить личные сообщения 
Вход 
